组织任务_Gradle中文网

有两种类型的任务：可操作任务和生命周期任务。

Gradle 中的可操作任务是执行实际工作的任务，例如编译代码。生命周期任务是指本身不工作的任务。这些任务没有任何操作，相反，它们捆绑了可操作的任务并作为构建的目标。

组织良好的生命周期任务设置可以增强新用户构建的可访问性，并简化与 CI 的集成。

生命周期任务

生命周期任务对于分离用户或机器之间的工作（CI 与本地）特别有利。例如，本地计算机上的开发人员可能不希望在每次更改时运行整个构建。

我们以一个app应用该插件的标准为例base。

Gradle插件定义了base多个生命周期任务，包括build、assemble和check。

我们通过将以下几行添加到构建脚本中来对build、check任务和任务进行分组：runapp

app/build.gradle.kts

tasks.build {
    group = myBuildGroup
}

tasks.check {
    group = myBuildGroup
    description = "Runs checks (including tests)."
}

tasks.named("run") {
    group = myBuildGroup
}

app/build.gradle

tasks.build {
    group = myBuildGroup
}

tasks.check {
    group = myBuildGroup
    description = "Runs checks (including tests)."
}

tasks.named('run') {
    group = myBuildGroup
}

如果我们现在查看app:tasks列表，我们可以看到三个任务可用：

$ ./gradlew :app:tasks

> Task :app:tasks

------------------------------------------------------------
Tasks runnable from project ':app'
------------------------------------------------------------

My app build tasks
------------------
build - Assembles and tests this project.
check - Runs checks (including tests).
run - Runs this project as a JVM application
tasksAll - Show additional tasks.

如果标准生命周期任务足够的话，这已经很有用了。移动组有助于澄清您期望在构建中使用的任务。

在许多情况下，您需要满足更具体的要求。一种常见的情况是运行质量检查而不运行测试。目前，该:check任务运行测试和代码质量检查。相反，我们希望始终运行代码质量检查，而不是冗长的测试。

为了添加质量检查生命周期任务，我们引入了一个名为的附加生命周期任务qualityCheck和一个名为的插件spotbugs。

要添加生命周期任务，请使用tasks.register().您唯一需要提供的就是名称。将此任务放入我们的组中，并使用以下方法连接属于此新生命周期任务的可操作任务dependsOn()：

app/build.gradle.kts

plugins {
    id("com.github.spotbugs") version "6.0.7"           // spotbugs plugin
}

tasks.register("qualityCheck") {                        // qualityCheck task
    group = myBuildGroup                                // group
    description = "Runs checks (excluding tests)."      // description
    dependsOn(tasks.classes, tasks.spotbugsMain)        // dependencies
    dependsOn(tasks.testClasses, tasks.spotbugsTest)    // dependencies
}

app/build.gradle

plugins {
    id 'com.github.spotbugs' version '6.0.7'            // spotbugs plugin
}

tasks.register('qualityCheck') {                        // qualityCheck task
    group = myBuildGroup                                // group
    description = 'Runs checks (excluding tests).'      // description
    dependsOn tasks.classes, tasks.spotbugsMain         // dependencies
    dependsOn tasks.testClasses, tasks.spotbugsTest     // dependencies
}

请注意，您不需要列出 Gradle 将执行的所有任务。只需在此处指定您要收集的目标即可。 Gradle 将确定需要调用哪些其他任务来实现这些目标。

在示例中，我们添加了一个classes任务，一个用于编译所有生产代码的生命周期任务，以及一个spotbugsMain检查我们的生产代码的任务。

我们还添加了将显示在任务列表中的描述，以帮助更好地区分这两个检查任务。

现在，如果运行“./gradlew :app:tasks”，我们可以看到新的qualityCheck生命周期任务可用：

$ ./gradlew :app:tasks

> Task :app:tasks

------------------------------------------------------------
Tasks runnable from project ':app'
------------------------------------------------------------

My app build tasks
------------------
build - Assembles and tests this project.
check - Runs checks (including tests).
qualityCheck - Runs checks (excluding tests).
run - Runs this project as a JVM application
tasksAll - Show additional tasks.

如果我们运行它，我们可以看到它运行 checkstyle 但不运行测试：

$ ./gradlew :app:qualityCheck

> Task :buildSrc:checkKotlinGradlePluginConfigurationErrors
> Task :buildSrc:generateExternalPluginSpecBuilders UP-TO-DATE
> Task :buildSrc:extractPrecompiledScriptPluginPlugins UP-TO-DATE
> Task :buildSrc:compilePluginsBlocks UP-TO-DATE
> Task :buildSrc:generatePrecompiledScriptPluginAccessors UP-TO-DATE
> Task :buildSrc:generateScriptPluginAdapters UP-TO-DATE
> Task :buildSrc:compileKotlin UP-TO-DATE
> Task :buildSrc:compileJava NO-SOURCE
> Task :buildSrc:compileGroovy NO-SOURCE
> Task :buildSrc:pluginDescriptors UP-TO-DATE
> Task :buildSrc:processResources UP-TO-DATE
> Task :buildSrc:classes UP-TO-DATE
> Task :buildSrc:jar UP-TO-DATE
> Task :app:processResources NO-SOURCE
> Task :app:processTestResources NO-SOURCE
> Task :list:compileJava UP-TO-DATE
> Task :utilities:compileJava UP-TO-DATE
> Task :app:compileJava
> Task :app:classes
> Task :app:compileTestJava
> Task :app:testClasses
> Task :app:spotbugsTest
> Task :app:spotbugsMain
> Task :app:qualityCheck

BUILD SUCCESSFUL in 1s
16 actionable tasks: 5 executed, 11 up-to-date

到目前为止，我们已经研究了各个子项目中的任务，当您在一个子项目中处理代码时，这对于本地开发非常有用。

通过此设置，开发人员只需知道他们可以调用 Gradle 来:subproject-name:tasks查看哪些任务可用且对他们有用。

全局生命周期任务

另一个调用生命周期任务的地方是在根构建中；这对于持续集成（CI）特别有用。

Gradle 任务在 CI 或 CD 系统中发挥着至关重要的作用，其中编译所有代码、运行测试或构建和打包完整应用程序等活动是典型的。为了实现这一点，您可以包含跨越多个子项目的生命周期任务。

Gradle 已经存在很长时间了，您会经常在根目录中观察到用于各种目的的构建文件。在较旧的 Gradle 版本中，许多任务是在根 Gradle 构建文件中定义的，从而导致各种问题。因此，确定该文件的内容时请务必小心。

应放置在根构建文件中的少数元素之一是全局生命周期任务。

我们继续以 Gradle initJava 应用程序多项目为例。

这次，我们将构建脚本合并到根项目中。我们将为全局生命周期任务建立两个组：一组用于与本地开发相关的任务，例如运行所有检查，另一个组专门用于我们的 CI 系统。

我们再次将列出的任务范围缩小到特定组：

build.gradle.kts

val globalBuildGroup = "My global build"
val ciBuildGroup = "My CI build"

tasks.named<TaskReportTask>("tasks") {
    displayGroups = listOf<String>(globalBuildGroup, ciBuildGroup)
}

build.gradle

def globalBuildGroup = "My global build"
def ciBuildGroup = "My CI build"

tasks.named(TaskReportTask, "tasks") {
    displayGroups = [globalBuildGroup, ciBuildGroup]
}

如果您愿意，可以通过更新来隐藏 CI 任务displayGroups。

目前，根项目没有公开任何任务：

$ ./gradlew :tasks

> Task :tasks

------------------------------------------------------------
Tasks runnable from root project 'gradle-project'
------------------------------------------------------------

No tasks

在此文件中，我们不应用插件！

让我们添加一个qualityCheckApp任务来执行子项目中的所有代码质量检查app。同样，出于 CI 目的，我们实现一个checkAll运行所有测试的任务：

build.gradle.kts

tasks.register("qualityCheckApp") {
    group = globalBuildGroup
    description = "Runs checks on app (globally)"
    dependsOn(":app:qualityCheck" )
}

tasks.register("checkAll") {
    group = ciBuildGroup
    description = "Runs checks for all projects (CI)"
    dependsOn(subprojects.map { ":${it.name}:check" })
    dependsOn(gradle.includedBuilds.map { it.task(":checkAll") })
}

build.gradle

tasks.register("qualityCheckApp") {
    group = globalBuildGroup
    description = "Runs checks on app (globally)"
    dependsOn(":app:qualityCheck")
}

tasks.register("checkAll") {
    group = ciBuildGroup
    description = "Runs checks for all projects (CI)"
    dependsOn subprojects.collect { ":${it.name}:check" }
    dependsOn gradle.includedBuilds.collect { it.task(":checkAll") }
}

因此，我们现在可以要求 Gradle 向我们显示根项目的任务，并且默认情况下，它只会向我们显示任务qualityCheckAll（以及可选的checkAll任务，具体取决于的值displayGroups）。

应该清楚用户应该在本地运行什么：

$ ./gradlew :tasks

> Task :tasks

------------------------------------------------------------
Tasks runnable from root project 'gradle-project'
------------------------------------------------------------

My CI build tasks
-----------------
checkAll - Runs checks for all projects (CI)

My global build tasks
---------------------
qualityCheckApp - Runs checks on app (globally)

如果我们运行该:checkAll任务，我们会看到它编译了所有代码并运行代码质量检查（包括spotbug）：

$ ./gradlew :checkAll

> Task :buildSrc:checkKotlinGradlePluginConfigurationErrors
> Task :buildSrc:generateExternalPluginSpecBuilders UP-TO-DATE
> Task :buildSrc:extractPrecompiledScriptPluginPlugins UP-TO-DATE
> Task :buildSrc:compilePluginsBlocks UP-TO-DATE
> Task :buildSrc:generatePrecompiledScriptPluginAccessors UP-TO-DATE
> Task :buildSrc:generateScriptPluginAdapters UP-TO-DATE
> Task :buildSrc:compileKotlin UP-TO-DATE
> Task :buildSrc:compileJava NO-SOURCE
> Task :buildSrc:compileGroovy NO-SOURCE
> Task :buildSrc:pluginDescriptors UP-TO-DATE
> Task :buildSrc:processResources UP-TO-DATE
> Task :buildSrc:classes UP-TO-DATE
> Task :buildSrc:jar UP-TO-DATE
> Task :utilities:processResources NO-SOURCE
> Task :app:processResources NO-SOURCE
> Task :utilities:processTestResources NO-SOURCE
> Task :app:processTestResources NO-SOURCE
> Task :list:compileJava
> Task :list:processResources NO-SOURCE
> Task :list:classes
> Task :list:jar
> Task :utilities:compileJava
> Task :utilities:classes
> Task :utilities:jar
> Task :utilities:compileTestJava NO-SOURCE
> Task :utilities:testClasses UP-TO-DATE
> Task :utilities:test NO-SOURCE
> Task :utilities:check UP-TO-DATE
> Task :list:compileTestJava
> Task :list:processTestResources NO-SOURCE
> Task :list:testClasses
> Task :app:compileJava
> Task :app:classes
> Task :app:compileTestJava
> Task :app:testClasses
> Task :list:test
> Task :list:check
> Task :app:test
> Task :app:spotbugsTest
> Task :app:spotbugsMain
> Task :app:check
> Task :checkAll

BUILD SUCCESSFUL in 1s
21 actionable tasks: 12 executed, 9 up-to-date

此页面是否有帮助？